*  JieJie Microelectronics H-Spice Model Library
*  Filename	: JMSH2010BTL_H v.20220923.txt
*  Product Name   : JMSH2010BTL (PowerJE®10x12)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 1.0
*  Release Date	: Sep 23, 2022
*  Junction Temp (Tj)	: -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSH2010BTL D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
RD D 1 0.007
RS S 3 1E-006
RG G 2 2.4
CGS 3 G 3.23e-9
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 8.0E-10
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
CDS D 3 POLY 7.65982E-9 -2.25251E-10 1.38434E-12 2.04538E-14 -3.18615E-16 1.53397E-18 -2.53655E-21

.model NMOS NMOS
+LEVEL = 3                     tlev = 1                      tlevc = 0       
+acm = 3                       VMAX = 1.0752E9               ETA = 1.21E-4  
+VTO = 3.787109                TOX = 1.043684E-9             NSUB = 9.6E19   
+KP = 278.563358               U0 = 424                      KAPPA = 0.178   
+GAMMA = 0.086261              PHI = 0.441402                THETA = 0.351842  
+BEX = -1.1                    TCV = 4.3E-4                  DELTA = 322.986337   

.model DCGD D
+CJO = 6.12E-10                VJ = 9.5                      M = 1.3    

.model DSUB D
+IS = 2.189094E-11             N = 1.058381                  RS = 1.132736E-3  
+BV = 208                      tlev = 0                      tlevc = 0    
+tref = 25                     eg = 1.192959                 keg = 1     
+gap1 = 3.63168E-3             gap2 = 1.108E3                xti = 0.199785   
+cta = 0                       ctp = 0                       tcv = 0    
+tm1 = 0                       tm2 = 0                       tpb = 0    
+tphp = 0                      trs = 0                       ttt1 = 0     
+ttt2 = 0                      xtitun = 3    

.model DLIM D
+IS = 1E-4   
.ends JMSH2010BTL

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************
